---

Jeg har lest og testet ut systemet med bilder i database som Jesper
Stocholm refererer til her:
http://groups.google.com/groups?q=stardeveloper&hl=en&group=dk.edb.internet.
webdesign.serverside.asp&safe=off&rnum=1&selm=Xns90F75B96E60ECspamstoc
holmdk%40192.38.208.81

Problemet er at jeg vil liste alle bildefilene fra databasen og har
kopiert nedenforviste script fra
http://www.activeserverpages.dk/aspdigital/kapitel2/sqlimage.asp

Sida min ser slik ut:
<%
Dim Image, teller
Set myConn = Server.CreateObject("ADODB.Connection")
Set rs = Server.CreateObject("ADODB.RecordSet")
strDSN = "DRIVER={Microsoft Access Driver
(*.mdb)};DBQ="&Server.MapPath("FileDB.mdb")
myConn.Open strDSN
teller=1
DO UNTIL teller=5
strSQL = "SELECT [File Data] FROM Files WHERE ID = " & teller
rs.Open strSQL, myConn, 1
If Not rs.EOF Then
strImage = rs("File Data").GetChunk(1024000)
Response.ContentType = "image/gif"
Response.BinaryWrite strImage
Else
Response.Write "Billedet findes ikke i databasen"
End If
teller=teller+1
LOOP
rs.Close
myConn.Close
Set rs = Nothing
Set myConn = Nothing
Response.End
%>

Men det eneste som skjer er at kun det første bildet vises. LOOP'en
fungerer ikke. Noen som har tips?
--
Herulf Skogheim
http://www.nord-troms.no

---

On Wed, 05 Sep 2001 22:08:24 GMT, herulf@nord-troms.no (Herulf
Skogheim) wrote:

[klip]

>Men det eneste som skjer er at kun det første bildet vises. LOOP'en
>fungerer ikke. Noen som har tips?

Mangler der ikke rs.MoveNext lige før LOOP???

Anders Lau

---

On Thu, 06 Sep 2001 01:08:38 +0200, Anders Lau Mandsholm
<lau@mandsholm.ingenspamtak.dk> wrote:

>Mangler der ikke rs.MoveNext lige før LOOP???
>
Stemmer. Men det hjalp ikke......??!

--
Herulf Skogheim
http://nord-troms.no

---

Herulf Skogheim wrote:
>
> Jeg har lest og testet ut systemet med bilder i database som Jesper
> Stocholm refererer til her:
> http://groups.google.com/groups?selm=Xns90F75B96E60ECspamstocholmdk@192.38.208.81
>
> Problemet er at jeg vil liste alle bildefilene fra databasen og har
> kopiert nedenforviste script fra
> http://www.activeserverpages.dk/aspdigital/kapitel2/sqlimage.asp
>
> Sida min ser slik ut:
> [...]
>
> Men det eneste som skjer er at kun det første bildet vises. LOOP'en
> fungerer ikke. Noen som har tips?

Det er jo fordi, du har misforstået et eller andet. Prøv:

=== list.asp - begin ===
<%
Dim Conn, Rs, Sql
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & _
Server.MapPath("FileDB.mdb")
Set rs = Server.CreateObject("ADODB.RecordSet")

Sql = "SELECT TOP 5 Id FROM Files ORDER BY Id"
rs.Open Sql, Conn, 0, 1, 1
Do Until Rs.Eof
Response.Write "<img src=""image.asp?id=" & rs("id") & """><br>"
Rs.MoveNext
Loop
rs.Close

Set rs = Nothing
Conn.Close
Set Conn = Nothing
%>
=== list.asp - end ===

=== image.asp - begin ===
<%
Dim Conn, Rs, Id, Sql
Id = CLng(Reqeust("Id"))
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & _
Server.MapPath("FileDB.mdb")
Set rs = Server.CreateObject("ADODB.RecordSet")

Sql = "SELECT [File Data] FROM Files WHERE Id=" & Id
rs.Open Sql, Conn, 0, 1, 1
If Not Rs.Eof Then
Response.ContentType = "image/gif"
Response.BinaryWrite rs("File Data").GetChunk(1024000)
Else
rs.Close
Response.Redirect "no_such_image.gif"
End If
rs.Close

Set rs = Nothing
Conn.Close
Set Conn = Nothing
%>
=== image.asp - end ===

--
Anders