---

Hej!
Jeg er ved at lave en dagbog med tilhørende billeder. Jeg vil
gerne have at det første billede skal vises som et stort billede
og de efterfølgende skal være thumbnails. Når man klikker på et
af de små billeder, skal det være dette billede, der vises som
stort billede. Jeg bruger en access-database.
Jeg har gjort følgende:

....
<%
pic = request.querystring("pic")
if pic = "" then
pic=1
end if
%>
</head>
...

og

...
p=0
Do until rspicture.eof
p=p+1

if p = pic then

%>
<div class="image">pic=<% = pic %> p=<% = p %>
<img src="..<% = StrImgPathShort %><% =rspicture("picture_name")
%>" alt="Billede">
</div>
<%
else
%>
<div class="thumb">pic=<% = pic %> p=<% = p %> <a
href="blogs.asp?pic=<% = p %>"><img src="..<% = StrThumbPathShort
%><% =rspicture("picture_thumb") %>" alt="Billede"></a></div>

<%
end if

rspicture.MoveNext
Loop
...

Resultatet af pic = "" kan ses på
http://www.revsbaeks.dk/aspupload/pic.jpg

Resultatet af pic = 4 kan ses på
http://www.revsbaeks.dk/aspupload/pic_4.jpg

Er der nogen, der kan gennemskue hvad, der er galt?
Eller måske har en bedre løsning?

Mvh Tina

--
Vil du lære at kode HTML, XHTML, CSS, SSI, ASP eller ASP.NET?
- Pædagogiske tutorials på dansk
- Kom godt i gang med koderne
KLIK HER! => http://www.html.dk/tutorials

---

Skunsen skrev:

> pic = request.querystring("pic")
> if pic = "" then
> pic=1
> end if

Hvis din querystring indeholder fx pic=4 svarer det til
tildelingen:

   pic = "4"

- i asp. Det er ikke det samme som tildelingen:

   pic = 4


> if p = pic then

Derfor bliver if-sætningen herover aldrig sand (4 <> "4"). Lav i
stedet et cast så det er samme type:

   If p = Cint(pic) Then

- eller:

   If Cstr(p) = pic Then

Den første er strengt taget mest logisk (da du jo sammenligner tal)
- men den vil på den anden side fejle, hvis pic ikke kan opfattes
som et heltal (fx hvis siden bliver kaldt med pic=p4).

Det kan så løses ved at teste om pic er numerisk i den if-sætning
der i forvejen tjekker om pic er udfyldt:

If pic = "" OR Not IsNumeric(pic) Then
   pic = 1
End If


> Resultatet af pic = "" kan ses på
> http://www.revsbaeks.dk/aspupload/pic.jpg

Hvis du har mulighed for det, er det bedre med et link direkte til
asp-siden. Så kan man se den html-kode der ligger bag billederne,
samt afprøve andre værdier i querystring.
--
Jens Gyldenkærne Clausen
Svar venligst under det du citerer, og citer kun det der er
nødvendigt for at forstå dit svar i sammenhængen. Se hvorfor og
hvordan på http://usenet.dk/netikette/citatteknik.html

---

> Hvis din querystring indeholder fx pic=4 svarer det til
> tildelingen:
>
>    pic = "4"
>
> - i asp. Det er ikke det samme som tildelingen:
>
>    pic = 4


Åhhh ja det er da klart!!! Det havde jeg slet ikke tænkt på!


> > Resultatet af pic = "" kan ses på
> > http://www.revsbaeks.dk/aspupload/pic.jpg
>
> Hvis du har mulighed for det, er det bedre med et link direkte til
> asp-siden. Så kan man se den html-kode der ligger bag billederne,
> samt afprøve andre værdier i querystring.

Sorry! En forglemmelse fra min side. Her er adressen

http://www.revsbaeks.dk/aspupload/blogs.asp?


Tusind tak for hjælpen!

mvh Tina



--
Vil du lære at kode HTML, XHTML, CSS, SSI, ASP eller ASP.NET?
- Pædagogiske tutorials på dansk
- Kom godt i gang med koderne
KLIK HER! => http://www.html.dk/tutorials

---

On 17 Nov 2005 10:05:55 GMT, Skunsen <junkmail@familienrevsbaek.dk>
wrote:

>>    pic = "4"
>>
>> - i asp. Det er ikke det samme som tildelingen:
>>
>>    pic = 4
>
>Åhhh ja det er da klart!!! Det havde jeg slet ikke tænkt på!

Den er vi vist mange der er faldet over i tidens løb ...

Mvh. Jørn

--
Jørn Andersen,
Brønshøj