Dennis Møller wrote:
> Selvfølgelig! At jeg ikke selv har set det... utroligt.
Jep, nogen gange er løsningen åbenlys, man skal bare kigge på det med
friske øjne. :)
> Nå, men jeg kan ikke helt hitte hoved og hale i de forslag du kommer med.
> Jeg har prøvet at copy/paste det, og det virker i hvert fald ikke.
Strange.. i bund og grund gør mit forslag det samme som dit; den samler
blot alle opdateringsforespørgsler i en fælles strSQL_priser_rediger,
der udføres efter løkken afsluttes. Du kan evt. udskrive din
strSQL_priser_rediger inden du executer den, for at se om alle de rette
poster kommer med?
Jeg prøver lige at rydde lidt op i koden; de lange sql-sætningslinier
gør det meget svært at læse og overskue. Jeg har forsøgt at opstille en
funktion til at udføre din gentagne Trim(Replace(Request.Form("xxxx" &
idnr))) for at gøre det lidt mere overskueligt. Du kan også evt. bruge
en underscore _ til at fortsætte din kode videre på næste linie for at
gøre det lidt mere læsevenligt. F.eks.:
myStr = "Denne string " &_
"fortsætter her som om der ingen linieskift var."
I bund og grund kan du sagtens nøjes med din egen løsning, da din
administratormodul ikke opdaterer de store datamængder - og det er næppe
en handling, der foretages ofte og af mange personer samtidig. Men det
er rart at kunne lave til andre, større opgaver.
-- annoteret justeret kode -------------
' ** funktionen til at sql-formattere en string fra request.form
' ** (' erstattes med '' og string sættes i '' efterfølgende)
function sqlformat(myStr)
sqlformat = "'" &_
Trim(Replace(Request.Form(myStr),"'","''")) &_
"'"
end function
iCount = CInt(Request.Form("iCount"))
' ** priser hentes fra databasen i recordset rs_priser
strSQL_priser = "SELECT id FROM priser"
Set rs_priser = Conn.Execute(strSQL_priser)
' ** sql-sætning til prisopdatering gøres klar
strSQL_priser_rediger = ""
' ** løkken startes her
while not rs_priser.eof
'** idnr hentes fra recordset
idnr = rs_priser("id")
' ** Sql-sætning til prisopdatering bygges op.
' ** Hver iteration bygger videre på den eksisterende sætning
' ** Sqlformat() sørger for at erstatte interne anførelsestegn
' ** og opstille anførelsestegn omrking værdien
' ** Vbnewline i enden giver linieskift, der letter fremvisning
' ** hvis man ønsker at få fremvist sql-sætningen
strSQL_priser_rediger = strSQL_priser_rediger &_
" Update priser set " &_
"navn = " & sqlformat("navn" & idnr) & ", " &_
"pris = " & sqlformat("pris" & idnr) & ", " &_
"betaling = " & sqlformat("betaling" & idnr) &_
"Where id = " & idnr & vbnewline
rs_priser.MoveNext
wend
' ** Fremvis sql-sætningen for at checke indholdet
' ** Hver linie burde indeholde sql til opdatering af
' ** 1 row i databasen.
response.write("<pre>" & strSQL_priser_rediger & "</pre>")
' ** Opdater databasen, sql-sætningen ikke er tom
if strSQL_priser_rediger <> "" then
Conn.Execute(strSQL_priser_rediger)
end if
-- annoteret justeret kode slut ---------
Hvad bruger du egentlig iCount-variablen til? Så vidt jeg kan se, bruger
du den ikke til noget under din opdatering?
t