Her kan du se hvordan du kan oprette et recordset fra bunden og indsætte data, som du kan sortere på efterfølgende.
Dette eksempel opretter et recordset med felterne (name, size), hvorefter der bliver lavet en dir af dit bibliotek som bliver lagt ind i recordsettet. Når dette er sket kan du så udskrive dit recordset i den rækkefølge du vil, i dette eksempel efter filnavn.
***************************************************
<!-- METADATA TYPE="typelib" FILE="C:\Program files\Common
files\System\ado\msado15.dll" -->
<%
Option Explicit
Dim objFSO '' Scripting.FileSystemObject
Dim objFolder '' Scripting.Folder
Dim objFile '' Scripting.File
Dim rsData '' ADODB.Recordset
Set rsData = Server.CreateObject("ADODB.Recordset")
With rsData.Fields
.Append "Filename", adVarChar, 40, adFldUpdatable
.Append "Size", adInteger, , adFldUpdatable
End With
rsData.Open , , adOpenDynamic
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(Server.MapPath("/"))
For Each objFile in objFolder.Files
rsData.AddNew
rsData("Filename") = objFile.Name
rsData("Size") = objFile.Size
rsData.Update
Next '' objFile
rsData.Sort = "Filename"
rsData.MoveFirst
Do Until rsData.EOF
Response.Write rsData("Filename") _
& " (" & rsData("Size") & " bytes)<br>"
rsData.MoveNext
Loop
rsData.Close
%>
***************************************************
>>Smilly
|